extends Node


@export var level_sets: Array[LevelSet] = []


var current_set_index: int = 0
var current_level_index: int = 0

var current_set: LevelSet:
	get():
		return level_sets[current_set_index]

var current_level: LevelInfo:
	get():
		return current_set.levels[current_level_index]


func _ready() -> void:
	SceneManager.current_scene_changed.connect(_on_current_scene_changed)


func get_level(set_idx: int, level_idx: int) -> LevelInfo:
	if set_idx >= level_sets.size():
		return null
	var lvl_set = level_sets[set_idx]
	if level_idx >= lvl_set.levels.size():
		return null
	return lvl_set.levels[level_idx]


func advance_level() -> void:
	var next_idx = current_level_index + 1
	
	# change scene to end-of-set scene if it is reached
	if next_idx >= current_set.levels.size():
		SceneManager.current_scene = current_set.end_scene.instantiate()
		return
	
	var level_info = current_set.levels[next_idx]
	var level = load(level_info.scene_path) as PackedScene
	if level:
		SceneManager.current_scene = level.instantiate()

func _detect_current_level() -> void:
	if not SceneManager.current_scene is Level:
		current_set_index = -1
		current_level_index = -1
		return
	
	for idx_set in level_sets.size():
		var level_set = level_sets[idx_set]
		for idx_lvl in level_set.levels.size():
			var level = level_set.levels[idx_lvl]
			if level.scene_path == SceneManager.current_scene.scene_file_path:
				current_set_index = idx_set
				current_level_index = idx_lvl
				return


func _on_current_scene_changed(_new_scene: Node) -> void:
	_detect_current_level()