extends CanvasLayer

#Console by hazel
#Const
const ENTRY_SEQUENCE = ["4", "1", "5"]
#Export

#Onready
onready var code_label = $CheatLabel
##Runtime
var lines: int = 0
var time: float = 0.0
var n: int = 0
var debug = false
var allow_sword = false
var moon_jump = false
var cfox_mode = false
var infinite_arrows = false
# cheat code entry
var entry_index = 0
var entry = false
var code = ""


func _ready():
	#Auto do debug when playtesting
	if not OS.is_debug_build():
		debug = false
	else:
		debug = true

func _physics_process(delta):
	#DEBUG
	if debug == true && !entry && !entry_index > 0:
		#Move player to mouse
		if Input.is_action_pressed("debug_move_player"):
			var nodes = get_tree().get_nodes_in_group("player")
			if not nodes.empty():
				var player = nodes[0]
				var mouse_position = SceneManager.viewport.get_mouse_position() / SceneManager.viewport_container.rect_scale
				mouse_position.x = clamp(mouse_position.x, 8.0, Game.resolution.x - 8.0)
				mouse_position.y = clamp(mouse_position.y, 8.0, Game.resolution.y - 8.0)
				var world_position = mouse_position + Game.current_sector * Game.resolution
				player.position = world_position
			
#			Game.get_map().get_node("Player").position = get_viewport().get_mouse_position()
#			Console.print(get_viewport().get_mouse_position())
		#Test room
		if Input.is_action_just_pressed("debug_testroom"):
			Game.change_map(load("res://maps/test_room.tscn"))
		#Debug 1
		if Input.is_action_just_pressed("debug_1"):
			Game.change_map(load("res://maps/level_select.tscn"))
		#Debug 2
		if Input.is_action_just_pressed("debug_2"):
			Game.freeze_frame(1.0)
	#Infinite arrows
	if infinite_arrows: Game.arrows = 99

func _input(event):
	if event is InputEventKey && event.is_pressed():
		var character = OS.get_scancode_string(event.scancode)
		if character.length() > 1:
			character = ""
		
		if entry:
			if event.scancode == KEY_ENTER:
				_enter_code()
				Game.set_deferred("can_pause",true)
				entry = false
				code = ""
			elif event.scancode == KEY_BACKSPACE:
				code.erase(code.length() - 1, 1)
			else:
				code += character
			code_label.text = code
		else:
			if character == ENTRY_SEQUENCE[entry_index]:
				entry_index += 1
				if entry_index >= ENTRY_SEQUENCE.size():
					entry = true
					entry_index = 0
					_on_entry()

func _on_entry():
	Audio.play_sound(Audio.a_star, Audio.ac_cheat)
	Game.can_pause = false

func _enter_code():
	match code:
		"30385":
			for gold in get_tree().get_nodes_in_group("gold"):
				var goldsprite = gold.get_node("AnimatedSprite")
				goldsprite.play("30385")
				goldsprite.position.y -= 1
				#goldsprite.material.set_shader_param("palette",load("res://graphics/collectibles/pal_star_green.png"))
		"1989":
			for enemy in get_tree().get_nodes_in_group("enemy"):
				enemy.die()
		"DGSTEEZY":
			debug = true
		"6DOUBLOONS":
			Console.print(get_tree().get_nodes_in_group("gold").size())
		"EVILSBANE":
			allow_sword = true
			Input.action_press("sword")
		"REDFEATHER":
			moon_jump = true
		"NIGHTCORE":
			Engine.time_scale = 10
		"UPUPANDAWAY":
			get_tree().call_group("mountain_easter_egg","play","liftoff")
		"MACOSX":
			var player = get_tree().get_nodes_in_group("player")[0]
			Game.instance_node(load("res://objects/environment/beach_ball/beach_ball.tscn"),player.global_position.x,player.global_position.y - 8,Game.get_map())
		"JUSTE":
			Game.get_map().get_node("Player").sprite.material.set_shader_param("border_color",Color.blue)
		"BEESKNEES":
			Game.get_map().rotation_degrees = -2
		"CFOX":
			cfox_mode = true
		"BANDANA":
			infinite_arrows = true